Amiga Plus 2002 #11/Amiga Plus CD - 2002 - No. 11.iso/Tools/Development/Feelin021015/Examples/Menus.e

Text File | 2002-10-28 | 4.6 KB | 142 lines

OPT PREPROCESS

MODULE 'feelin','libraries/feelin','a4'

PROC main()
   DEF c,w,m,m1,m2,m3,cntxt,label

   sys_SGlob()

   IF feelinbase := OpenLibrary('feelin.library',FV_VERSION)
      m := Menu('Project'),
         Child, Item('Clear'), End,
         Child, Item('New'), End,
         Child, ItemSeparator,

         Child, m1 := Menu('Load'),
            Child, Item('Reload'), End,
            Child, ItemSeparator,
            Child, Item('Open...'), End,
            Child, Item('Open New...'), End,
            Child, ItemSeparator,
            Child, Item('Insert...'), End,
            Child, Item('Append...'), End,
            Child, ItemSeparator,
            Child, Item('Load Session...'), End,
         End,

         Child, m2 := Menu('Save'),
            Child, Item('Save'), End,
            Child, Item('Save As...'), End,
            Child, ItemSeparator,
            Child, Item('Save Session...'), End,
         End,

         Child, Item('Iconify'), End,
         Child, Item('`bQuit'),   FA_ID,"QUIT", End,
         Child, ItemSeparator,

         Child, m3 := Menu('Many levels'),
            Child, Item('Item 1.1'),End,
            Child, Menu('Menu 1.2'),
               Child, Item('Item 2.1'), End,
               Child, Item('Item 2.2'), End,
               Child, Menu('Menu 2.3'),
                  Child, Menu('Menu 3.1'),
                     Child, Item('Item 4.1'), End,
                     Child, Item('Item 4.2'), End,
                     Child, Item('Item 4.3'), End,
                  End,

                  Child, Item('Item 3.2'), End,
               End,
            End,
            Child, Item('Item 1.3'), End,
         End,
      End

      IF m
         c := ClientObject,
            Child, w := WindowObject, FA_Window_Title, 'Feelin : Menus', FA_ContextMenu,m, FA_UserData,'Window',
               Child, VGroup, NoFrame,
                  Child, TextObject,
                         FA_ChainToCycle,          FALSE,
                         FA_FixedHeight,           TRUE,
                         FA_TextDisplay_Interline, 2,
                         FA_Text, '`cHere, all `<8>ContextMenus`<0> are children of\na big `<8>Menu`<0> (also used by the window).\n`i`Se`SsSo good for Monica !!`Sn`n\nLuckely you only have to listen\nto your `<8>Client`<0> to know everything\n about the whole menu.\n`i`Se`SsHummm, even better.`n`Sn\nMore over, `<8>multiselection`<0> is handled magically.',
                         End,

                  Child, BarTitle('Taste my context'),

                  Child, VGroup, FA_Group_HSpacing, 0, FA_Group_VSpacing, 0,
                     Child, TextObject, DontChain, TextFrame, TextBack, FA_ContextMenu, m, FA_Text,'`c`SeComplete Menu', FA_Text_VCenter, TRUE, FA_UserData,'Complete', End,

                     Child, HGroup, FA_Group_HSpacing, 0, FA_Group_VSpacing, 0,
                        Child, TextObject, DontChain, TextFrame, TextBack, FA_ContextMenu, m1, FA_Text, '`c`SeLoad Menu', FA_Text_VCenter, TRUE, FA_UserData, 'Load Menu', End,
                        Child, TextObject, DontChain, TextFrame, TextBack, FA_ContextMenu, m2, FA_Text, '`c`SeSave Menu', FA_Text_VCenter, TRUE, FA_UserData, 'Save Menu', End,
                     End,

                     Child, TextObject, DontChain, TextFrame, TextBack, FA_ContextMenu, m3, FA_Text,'`c`SeMany Levels', FA_Text_VCenter, TRUE, FA_UserData, 'Levels', End,
                  End,

                  Child, BarTitle('Menu Selection(s)'),

                  Child, VGroup, StringFrame,StringBack, FA_FixedHeight,TRUE, FA_Group_VSpacing,2,
                     Child, cntxt := TextObject,DontChain, FA_Back, FI_Dark, FA_Text_PreParse,'`c`<1>', FA_Text_VCenter,TRUE, FA_Text_SetMin,TRUE, FA_Text_Static,FALSE, End,
                     Child, label := TextObject,DontChain, FA_Back, FI_Dark, FA_Text_PreParse,'`c`<1>', FA_Text_VCenter,TRUE, FA_Text_SetMin,TRUE, FA_Text_Static,FALSE, End,
                  End,
               End,
            End,
         End

         IF c
            F_DoA(c,FM_Notify,[FA_Menu_Action,
                               FV_Notify_Always,FV_Notify_Self, 5,
                               FM_CallDispatcher,{disp_menu},FV_Notify_Value,label,cntxt])

            F_DoA(w,FM_Notify,[FA_Window_CloseRequest,TRUE,FV_Notify_Client, 2,FM_Client_ReturnID,FV_Client_Quit])
            F_Set(w,FA_Window_Open,TRUE)

            F_DoA(c,FM_Client_Run,NIL)

            F_DisposeObj(c)
         ENDIF

         F_DisposeObj(m)
      ENDIF

      CloseLibrary(feelinbase)
   ENDIF
ENDPROC

PROC disp_menu(client=A0:PTR TO feelinObject,args=A1:PTR TO LONG)
   DEF menu:PTR TO feelinObject,label:PTR TO feelinObject,cntxt:PTR TO feelinObject,
       next:PTR TO feelinObject,node:PTR TO FS_SelectedNode,str[80]:STRING,mul=FALSE

   sys_RGlob()

   menu  := args[0]
   label := args[1]
   cntxt := args[2]

   IF node := F_Get(menu,FA_Menu_Owner)
      StringF(str,'`<8>ContextOwner`<1> 0x\h - \a\s\a',node,F_Get(node,FA_UserData))
      F_Set(cntxt,FA_Text,str)
   ELSE
      F_Set(cntxt,FA_Text,'No Context')
   ENDIF

   IF next := F_Get(menu,FA_Menu_Selected)
      IF next.next
         F_Set(label,FA_Text,'`<8>!! Multiple !!`<1>') ; mul := TRUE
      ENDIF

      WHILE node := F_NextObject({next})
         IF mul THEN Delay(50)
         IF F_Get(node.object,FA_ID) = "QUIT" THEN F_DoA(client,FM_Client_ReturnID,[FV_Client_Quit])
         StringF(str,'`<8>Item`<1> 0x\h - `<8>Title`<1> \s',node.object,F_Get(node.object,FA_Item_Title))
         F_Set(label,FA_Text,str)
      ENDWHILE
   ENDIF
ENDPROC